import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=1199;bottom=899)
winform.add()
/*}}*/
 
winform.show();
import godking.paint
import godking.motion
var p = godking.paint(200*6,150*6,0xFFFFFFFF);
p.offsetMode =false
for(y=1;6;1){
	for(x=1;6;1){
		var l = (x-1)*200;
		var t = (y-1)*150;
		var index = (y-1)*6+x;
		if index>33 break 2;
		var funcname = index++"："++godking.motion.types[index].name++" ("++godking.motion.types[index].nickname++")  "++godking.motion.types[index].memo
		p.drawRectF(l,t,200,150,0xFF000000,1);
		p.drawTextF(l+2,t+2/*y1*/,/*x2*/200,100/*y2*/,funcname,::LOGFONT(name="宋体";h=12;color=0xFF000000;brush=null),0,0,0);
		p.drawLine(l,t+20,l+200,t+20,0xFF00FFDD,1/*线宽*/);
		p.drawLine(l,t+130,l+200,t+130,0xFF00FFDD,1/*线宽*/);
		var smFunc = godking.motion(index/*缓动类型*/);
		for(n=1;200;1){
			var Y = smFunc(t+130/*Y开始值*/,t+20/*Y结束值*/,n/200/*X当前值*/);
			p.setPixel(l+n,Y,0xFFFF0000/*颜色ARGB*/);
		}
		winform.add({
			["button"++index]={cls="plus";text="➡";left=l;top=t+50;right=l+20;bottom=t+70;z=2;bgcolor=255;color=65535;notify=1;};
		})
		winform["button"++index].oncommand = function(){
			for(i=0;100;1){
				var Y = smFunc(l/*Y开始值*/,l+180/*Y结束值*/,i/100/*X当前值*/);
				owner.setPos(Y,t+50);
				owner.redraw();
				win.delay(10);
			}
		}
	}
}
winform.setBitmap(p.bitmap.copyHandle());
winform.redraw();
win.loopMessage();